Example Batch Files

This is an example for standalone-operation with 2 errorlevel events defined. Event 1 returns level 10, event 2 returns level 20. No echomail and netmail is used.

:Loop
PROBOARD -S
if errorlevel 100 goto End
if errorlevel 99 goto End
if errorlevel 20 goto Event2
if errorlevel 10 goto Event1
if errorlevel 1 goto FatalError
goto Loop
:Event1
echo Perform some actions
echo --------------------
goto Loop
:Event2
echo Perform some more actions
echo -------------------------
goto Loop
:FatalError
echo FATAL ERROR - ProBoard Down
:End

Using ProBoard with a frontend-mailer is a little more complicated. This is an example for use with FrontDoor.

In this example FrontDoor uses the following errorlevels:

300 bps call : 50
1200 bps call : 51
2400 bps call : 52
Local call : 60
Mail received : 100
Exit : 150

SET FD=C:\FD
:Loop
cd \fd
fd
if errorlevel 150 goto End
if errorlevel 100 goto MailRcv
cd\pb
if errorlevel 60 goto Local
if errorlevel 52 goto Call2400
if errorlevel 51 goto Call1200
if errorlevel 50 goto Call300
:FatalErr
echo FATAL ERROR
goto End
:Call300
proboard -b300 -p1
goto CheckPBErr
:Call1200
proboard -b1200 -p1
goto CheckPBErr
:Call2400
proboard -b2400 -p1
goto CheckPBErr
:Local
proboard
:CheckPBErr
if errorlevel 100 goto End
if errorlevel 5 goto NetEcho
if errorlevel 4 goto EchoEntered
if errorlevel 3 goto NetEntered
if errorlevel 1 goto FatalErr
goto Loop
:NetEcho
REM ************************************
REM ** Export netmail & echomail here **
REM ************************************
Goto Loop
:NetEntered
REM ************************************
REM ** Export netmail here **
REM ************************************
Goto Loop
:EchoEntered
REM ************************************
REM ** Export echomail here **
REM ************************************
Goto Loop
:MailRcv
REM ************************************
REM ** Unpack and Import mail here **
REM ************************************
Goto Loop
:End